宁夏网络公司|宁夏網站建設|银川网络公司|银川網站建設
  15595599605 13309518098 掃描加微信:
   
網站首頁 | 網站建設 | 澳门网上老虎机平台 | 網絡營銷 | 常見問題 | 相關知識 | 聯系我們 | 客戶案例
售前: 15595599605
13309518098
售後: 13014290997
15008617747
QQ:  建站咨詢
 建站咨詢
 業務受理
 售後服務
套餐类型 一 低级型 2015-02-10
套餐类型 二 经济型 2015-02-10
套餐类型 三 普通型 2015-02-10
套餐类型 四 标准型 2015-02-10
套餐类型 五 行业型 2015-02-10
套餐类型 六 门户型 2015-02-10
您的位置:網站首頁>>>一套簡單的asp驗證碼的步伐
一套簡單的asp驗證碼的步伐
作者:澳门老虎机平台四方電子科技有限公司  來源:本站整理  
宣布时间:2010-07-05 16:53:58  宣布人:志达四方

包罗三個ASP頁面

一:index.asp(用于調用驗證碼,並提交驗證碼至“from.asp”

<form method="post" action="from.asp">
<input name="Form_Code" type="text" /><input name="Submit1" type="submit" value="提交" />
<SCRIPT language=javascript> document.write("<img src=code.asp align=absmiddle id=Image1 onclick=Image1.src='code.asp?'+Math.random(); alt=看不清楚/>");</SCRIPT>
</form>

二:code.asp(用于生成驗證碼)

<%
Option Explicit        ' 显示声明
Class Com_GifCode_Class
    Public Noisy, Count, Width, Height, Angle, Offset, Border
    Private Graph(), Margin(3)
    Private Sub Class_Initialize()
        Randomize
        Noisy    = 0    ' 滋扰点出现的概率
        Count    = 6    ' 字符数量
        Width    = 80    ' 图片宽度
        Height    = 18    ' 图片高度
        Angle    = 1    ' 角度随机变革量
        Offset    = 10    ' 偏移随机变革量
        Border = 2    ' 边框巨细
    End Sub
    Public Function Create()
        Const cCharSet = "123456789"
        Dim i, x, y
        Dim vValidCode : vValidCode = ""
        Dim vIndex
        ReDim Graph(Width-1, Height-1)
        For i = 0 To Count - 1
            vIndex = Int(Rnd * Len(cCharSet))
            vValidCode = vValidCode + Mid(cCharSet, vIndex+1 , 1)
            SetDraw vIndex, i
        Next
        Create = vValidCode
    End Function
    Sub SetDot(pX, pY)
        If pX * (Width-pX-1) >= 0 And pY * (Height-pY-1) >= 0 Then
            Graph(pX, pY) = 1
        End If
    End Sub
    Public Sub SetDraw(pIndex, pNumber)
        ' 字符数据
        Dim DotData(8)
        DotData(0) = Array(30, 15, 50, 1, 50, 100)
        DotData(1) = Array(1 ,34 ,30 ,1 ,71, 1, 100, 34, 1, 100, 93, 100, 100, 86)
        DotData(2) = Array(1, 1, 100, 1, 42, 42, 100, 70, 50, 100, 1, 70)
        DotData(3) = Array(100, 73, 6, 73, 75, 6, 75, 100)
        DotData(4) = Array(100, 1, 1, 1, 1, 50, 50, 35, 100, 55, 100, 80, 50, 100, 1, 95)
        DotData(5) = Array(100, 20, 70, 1, 20, 1, 1, 30, 1, 80, 30, 100, 70, 100, 100, 80, 100, 60, 70, 50, 30, 50, 1, 60)
        DotData(6) = Array(6, 26, 6, 6, 100, 6, 53, 100)
        DotData(7) = Array(100, 30, 100, 20, 70, 1, 30, 1, 1, 20, 1, 30, 100, 70, 100, 80, 70, 100, 30, 100, 1, 80, 1, 70, 100, 30)
        DotData(8) = Array(1, 80, 30, 100, 80, 100, 100, 70, 100, 20, 70, 1, 30, 1, 1, 20, 1, 40, 30, 50, 70, 50, 100, 40)
        Dim vExtent : vExtent = Width / Count
        Margin(0) = Border + vExtent * (Rnd * Offset) / 100 + Margin(1)
        Margin(1) = vExtent * (pNumber + 1) - Border - vExtent * (Rnd * Offset) / 100
        Margin(2) = Border + Height * (Rnd * Offset) / 100
        Margin(3) = Height - Border - Height * (Rnd * Offset) / 100
        Dim vStartX, vEndX, vStartY, vEndY
        Dim vWidth, vHeight, vDX, vDY, vDeltaT
        Dim vAngle, vLength
        vWidth = Int(Margin(1) - Margin(0))
        vHeight = Int(Margin(3) - Margin(2))
        ' 起始坐标
        vStartX = Int((DotData(pIndex)(0)-1) * vWidth / 100)
        vStartY = Int((DotData(pIndex)(1)-1) * vHeight / 100)
        Dim i, j
        For i = 1 To UBound(DotData(pIndex), 1)/2
            If DotData(pIndex)(2*i-2) <> 0 And DotData(pIndex)(2*i) <> 0 Then
                ' 终点坐标
                vEndX = (DotData(pIndex)(2*i)-1) * vWidth / 100
                vEndY = (DotData(pIndex)(2*i+1)-1) * vHeight / 100
                ' 横向差距
                vDX = vEndX - vStartX
                ' 纵向差距
                vDY = vEndY - vStartY
                ' 倾斜角度
                If vDX = 0 Then
                    vAngle = Sgn(vDY) * 3.14/2
                Else
                    vAngle = Atn(vDY / vDX)
                End If
                ' 两坐标距离
                If Sin(vAngle) = 0 Then
                    vLength = vDX
                Else
                    vLength = vDY / Sin(vAngle)
                End If
                ' 随机转动角度
                vAngle = vAngle + (Rnd - 0.5) * 2 * Angle * 3.14 * 2 / 100
                vDX = Int(Cos(vAngle) * vLength)
                vDY = Int(Sin(vAngle) * vLength)
                If Abs(vDX) > Abs(vDY) Then vDeltaT = Abs(vDX) Else vDeltaT = Abs(vDY)
                For j = 1 To vDeltaT
                    SetDot Margin(0) + vStartX + j * vDX / vDeltaT, Margin(2) + vStartY + j * vDY / vDeltaT
                Next
                vStartX = vStartX + vDX
                vStartY = vStartY + vDY
            End If
        Next
    End Sub
    Public Sub Output()
        Response.Expires = -9999
        Response.AddHeader "pragma", "no-cache"
        Response.AddHeader "cache-ctrol", "no-cache"
        Response.ContentType = "image/gif"
        ' 文件类型
        Response.BinaryWrite ChrB(Asc("G")) & ChrB(Asc("I")) & ChrB(Asc("F"))
        ' 版本信息
        Response.BinaryWrite ChrB(Asc("8")) & ChrB(Asc("9")) & ChrB(Asc("a"))
        ' 逻辑屏幕宽度
        Response.BinaryWrite ChrB(Width Mod 256) & ChrB((Width \ 256) Mod 256)
        ' 逻辑屏幕高度
        Response.BinaryWrite ChrB(Height Mod 256) & ChrB((Height \ 256) Mod 256)
        Response.BinaryWrite ChrB(128) & ChrB(0) & ChrB(0)
        ' 全局颜色列表配景颜色
        Response.BinaryWrite ChrB(0) & ChrB(0) & ChrB(0)
        ' 文字颜色
        Response.BinaryWrite ChrB(255) & ChrB(255) & ChrB(0)
        ' 图象标识符
        Response.BinaryWrite ChrB(Asc(","))
        Response.BinaryWrite ChrB(0) & ChrB(0) & ChrB(0) & ChrB(0)
        ' 图象宽度
        Response.BinaryWrite ChrB(Width Mod 256) & ChrB((Width \ 256) Mod 256)
        ' 图象高度
        Response.BinaryWrite ChrB(Height Mod 256) & ChrB((Height \ 256) Mod 256)
        Response.BinaryWrite ChrB(0) & ChrB(7) & ChrB(255)
        Dim x, y, i : i = 0
        For y = 0 To Height - 1
            For x = 0 To Width - 1
                If Rnd < Noisy / 100 Then
                    Response.BinaryWrite ChrB(1-Graph(x, y))
                Else
                    If x * (x-Width) = 0 Or y * (y-Height) = 0 Then
                        Response.BinaryWrite ChrB(Graph(x, y))
                    Else
                        If Graph(x-1, y) = 1 Or Graph(x, y) Or Graph(x, y-1) = 1 Then
                            Response.BinaryWrite ChrB(1)
                        Else
                            Response.BinaryWrite ChrB(0)
                        End If
                    End If
                End If
                If (y * Width + x + 1) Mod 126 = 0 Then
                    Response.BinaryWrite ChrB(128)
                    i = i + 1
                End If
                If (y * Width + x + i + 1) Mod 255 = 0 Then
                    If (Width*Height - y * Width - x - 1) > 255 Then
                        Response.BinaryWrite ChrB(255)
                    Else
                        Response.BinaryWrite ChrB(Width * Height Mod 255)
                    End If
                End If
            Next
        Next
        Response.BinaryWrite ChrB(128) & ChrB(0) & ChrB(129) & ChrB(0) & ChrB(59)
    End Sub
End Class
'刷新
Response.expires=-1
Response.AddHeader"pragma","no-cache"
Response.AddHeader"cache-control","no-store"
    Dim mCode
    Set mCode = New Com_GifCode_Class
    Session("GetCode") = mCode.Create()    ' 将验证码存到Session中
    mCode.Output()    ' 输出数据
    Set mCode = Nothing
%>

二:from.asp(用于接收驗證碼)

<%
If IsEmpty(Session("GetCode")) Or Session("GetCode") <> UCase(Request.form("Form_Code")) Then
Response.Write "<script>alert('验证码输入错误!');history.go(-1)</script>"
Response.End
Else
Session("GetCode") = Empty    ' 清空Session
End If
%>

-------------------------------------------------------------------------------------------------

業務範圍:網站建設 网页设计 网站制作 网页制作 手機網站 微信網站

编辑:【澳门老虎机平台四方電子科技有限公司】录入:【網站建設部】

】 【返回】 【打印】 【關閉

     
營業執照 組織機構 稅務登記 宁静網站
 
澳门老虎机平台四方電子科技有限公司
业务电话:15595599605 13309518098
客服热线:13014290997 15008617747
地址:銀川市金鳳區康平路悅海新天地購物廣場
E-mail:49773161@qq.com
在線客服:点击这里给我发消息 点击这里给我发消息 点击这里给我发消息
版權所有 © 2015 澳门老虎机平台四方電子科技有限公司 甯ICP備05000522號  宁公网安备 64010602000041号